{Model of Persistence and Resistance in Batch culture}
{Hill function for antibiotic concentration dependent growth}
{FS(a) = FMax - [(FMax- FMin)(a/MIC)­]/[(a/MIC) - FMin/FMax]}
METHOD EULER
STARTTIME = 0
STOPTIME=50
DT = 0.001
DTOUT =.2
{Parameters}
fmaxs=1 {Maximum growth rate sensitive}
fmins= -3{Minimum growth rate sensitive}
fmaxn=0.001 {Maximum growth rate persistent}
fminn=-0.001 {Minimum growth rate persistent}
fmaxr=1 {Maximum growth resistant}
fminr=-3 {Minimum growth rate resistant}
mics =1 {MIC - sensitive}
micn = 1 {MIC - persistent}
micr =20 {MIC Resistant}
ksat = 2e9{Saturation level}
ks=1 {Hill Coefficient - sensitive}
kn=1 {Hill coefficient - persistent}
kr = 1 {Hill Coefficient - resistant}
d =0 {Antibiotic decay rate}
xsn = 0.00001 {Switch from S - > N}
xns = 0.00001 {Switch from  N-->S}
mur = 1e-18 {Mutation rate S->R}
vol = 1 {Volume of habitat}
{Variables}
init A =0 {Initial Antibiotic concentration}
init S=2e8 {Initial density of sensitive bacteria}
init N=1 {Initial density persistent}
init R=1 {Initial density resistant}
{Equations}
d/dt (A) = -d*A {change in the concentration of the antibiotic}
psis = ((fmaxs-fmins)*(A/mics)^ks)/((A/mics)^ks - fmins/fmaxs)
psin = ((fmaxn-fminn)*(A/micn)^kn)/((A/micn)^kn - fminn/fmaxn)
psir = ((fmaxr-fminr)*(A/micr)^kn)/((A/micr)^kr - fminr/fmaxr)
d/dt (S) =(S*fmaxs - psis*S)*(1-Nt/ksat) -xsn*S+xns*N
d/dt (N) =(N*fmaxn - psin*N)*(1-Nt/ksat)+xsn*S - xns*N {Change in the density
of persistent}
d/dt (R) = (R*fmaxr - psir*R)*(1-Nt/ksat)+GR/vol {Change in the density of
resistant}
Nt=S+ N +R
{Mutation to resistance}
bn = (S+N)*mur*dt*vol
rm =RANDOM (0, 1)
GR = IF rm < bn THEN 1/DT ELSE 0